dbc522a224
Modified weapon scripts to eliminate specialized projectile behavior - allows charged weapons to have projectiles and modify weapon stats when charged Added machine gun weapon & VFX Moved third party code to Plugins folder to improve compile times
74 lines
2.4 KiB
HLSL
74 lines
2.4 KiB
HLSL
//
|
|
// Noise Shader Library for Unity - https://github.com/keijiro/NoiseShader
|
|
//
|
|
// Original work (webgl-noise) Copyright (C) 2011 Ashima Arts.
|
|
// Translation and modification was made by Keijiro Takahashi.
|
|
//
|
|
// This shader is based on the webgl-noise GLSL shader. For further details
|
|
// of the original shader, please see the following description from the
|
|
// original source code.
|
|
//
|
|
|
|
//
|
|
// Description : Array and textureless GLSL 2D simplex noise function.
|
|
// Author : Ian McEwan, Ashima Arts.
|
|
// Maintainer : ijm
|
|
// Lastmod : 20110822 (ijm)
|
|
// License : Copyright (C) 2011 Ashima Arts. All rights reserved.
|
|
// Distributed under the MIT License. See LICENSE file.
|
|
// https://github.com/ashima/webgl-noise
|
|
//
|
|
|
|
#include "SimplexNoise2D.cginc"
|
|
|
|
float2 snoise_grad(float2 v)
|
|
{
|
|
const float4 C = float4( 0.211324865405187, // (3.0-sqrt(3.0))/6.0
|
|
0.366025403784439, // 0.5*(sqrt(3.0)-1.0)
|
|
-0.577350269189626, // -1.0 + 2.0 * C.x
|
|
0.024390243902439); // 1.0 / 41.0
|
|
// First corner
|
|
float2 i = floor(v + dot(v, C.yy));
|
|
float2 x0 = v - i + dot(i, C.xx);
|
|
|
|
// Other corners
|
|
float2 i1;
|
|
i1.x = step(x0.y, x0.x);
|
|
i1.y = 1.0 - i1.x;
|
|
|
|
// x1 = x0 - i1 + 1.0 * C.xx;
|
|
// x2 = x0 - 1.0 + 2.0 * C.xx;
|
|
float2 x1 = x0 + C.xx - i1;
|
|
float2 x2 = x0 + C.zz;
|
|
|
|
// Permutations
|
|
i = mod289(i); // Avoid truncation effects in permutation
|
|
float3 p =
|
|
permute(permute(i.y + float3(0.0, i1.y, 1.0))
|
|
+ i.x + float3(0.0, i1.x, 1.0));
|
|
|
|
float3 m = max(0.5 - float3(dot(x0, x0), dot(x1, x1), dot(x2, x2)), 0.0);
|
|
float3 m2 = m * m;
|
|
float3 m3 = m2 * m;
|
|
float3 m4 = m2 * m2;
|
|
|
|
// Gradients: 41 points uniformly over a line, mapped onto a diamond.
|
|
// The ring size 17*17 = 289 is close to a multiple of 41 (41*7 = 287)
|
|
float3 x = 2.0 * frac(p * C.www) - 1.0;
|
|
float3 h = abs(x) - 0.5;
|
|
float3 ox = floor(x + 0.5);
|
|
float3 a0 = x - ox;
|
|
|
|
// Normalise gradients
|
|
float3 norm = taylorInvSqrt(a0 * a0 + h * h);
|
|
float2 g0 = float2(a0.x, h.x) * norm.x;
|
|
float2 g1 = float2(a0.y, h.y) * norm.y;
|
|
float2 g2 = float2(a0.z, h.z) * norm.z;
|
|
|
|
// Compute gradient of noise function at P
|
|
float2 grad =
|
|
-6.0 * m3.x * x0 * dot(x0, g0) + m4.x * g0 +
|
|
-6.0 * m3.y * x1 * dot(x1, g1) + m4.y * g1 +
|
|
-6.0 * m3.z * x2 * dot(x2, g2) + m4.z * g2;
|
|
return 130.0 * grad;
|
|
}
|